Arduino as a Network Monitor

I have set up an Arduino as a Network monitor so I can be silently alerted if a WEB server on the LAN/Internet goes down. In a previous post, here, I show the relay circuit I am using in this sketch to flash a CFL lamp. This sketch also uses the same ENC28J60 module to connect to the LAN/Internet.

The uniqueness of this code is that it uses PING against multiple servers. I tried and tried to get this function using the UIPEthernet library working without success. I finally switched to the EtherCard library and found the solution for PINGing multiple servers. The EtherCard library also solves the problem of the CS Pin on the Arduino Leonardo that I document here. (The EtherCard library allows the code to select which pin will be used for the CS pin.)

There are several interesting things to note about this sketch:

1. It uses PROGMEM so the IP Addresses are preserved thru each PING loop
2. The IP address for the ENC28J60 module is dynamically set (the comments show how to switch to a static IP)
3. MAXCYCLES can be set to re-ping and not alert in case your LAN is not perfect (the device you are pinging might miss a few)
4. Since this is wired as a temporary setup, I blink the light when the sketch first starts to make sure the wiring is correct
5. An LCD is used to display the IP address and millisecond PING times (this same info is also displayed to the serial port)

Here is the sketch:

// From earl@microcontrollerelectronics.com

#include <avr/pgmspace.h>
#include <EtherCard.h>
#include <LiquidCrystal.h>

#define CS_PIN        10
#define pinToToggle   9

static byte mymac[] = { 0x74,0x69,0x69,0x2D,0x30,0x31 };

// myip,gwip,mask,dns Only needed if using a Static IP
static byte myip[]  = { 192,168,2,50 };
static byte gwip[]  = { 192,168,2,1 };
static byte mask[]  = { 255,255,255,0 };
static byte dns[]   = { 8,8,8,8 };

byte Ethernet::buffer[700];
static int32_t timer;
static int polling;

//change these to the IPs that you want to ping
const char srv0[]  PROGMEM = "192.168.2.1";
const char srv1[]  PROGMEM = "192.168.0.105";
const char srv2[]  PROGMEM = "192.168.2.104";
const char srv3[]  PROGMEM = "192.168.0.103";
const char srv4[]  PROGMEM = "192.168.2.101";
const char srv5[]  PROGMEM = "192.168.2.153";
const char srv6[]  PROGMEM = "192.168.0.107";
const char srv7[]  PROGMEM = "192.168.0.104";
const char srv8[]  PROGMEM = "192.168.2.102";
const char srv9[]  PROGMEM = "192.168.0.176";

// Make sure this list matches the above list
const char* const servers[] PROGMEM = {srv0,srv1,srv2,srv3,srv4,srv5,srv6,srv7,srv8,srv9};

#define NUMSRVRS (sizeof(servers) / sizeof(servers[0]))
#define MAXCYCLES 3
#define PING_DELAY 2000000

static int cycles;

char sbuffer[30];

static int i;

float ms;

long interval              = 500;
unsigned long currentTime  = 0;
unsigned long previousTime = 0;

LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

void blink() {
  currentTime = millis();
  if(currentTime - previousTime > interval) {
    previousTime = currentTime;
    digitalWrite(pinToToggle, !digitalRead(pinToToggle));
  }
}

static void gotPinged (byte* ptr) {
  ether.printIp(">>> ping from: ", ptr);
} 

void setup () {
  
  pinMode(pinToToggle,OUTPUT);
  
  lcd.begin(16, 2);
    
  Serial.begin(57600);

// Uncomment to wait till serial port is ready
//  while (!Serial) { }

  Serial.println(F("Ping Servers\n"));
  
  if (!ether.begin(sizeof Ethernet::buffer, mymac, CS_PIN))
    Serial.println(F("Failed to access Ethernet controller\n"));
  
  strcpy_P(sbuffer, (char*)pgm_read_word(&(servers[0])));
  ether.parseIp(ether.hisip,sbuffer);

// Comment these two lines and uncomment staticSetup
// to use static vs DHCP IP address
  if (!ether.dhcpSetup())
    Serial.println(F("DHCP failed\n"));
    
//  if (!ether.staticSetup(myip, gwip, dns, mask))
//    Serial.println(F("Failed to set Static IP"));

  while (ether.clientWaitingGw())
    ether.packetLoop(ether.packetReceive());
  
  Serial.println("Gateway found");
  
  ether.printIp("IP:  ",     ether.myip);
  ether.printIp("GW:  ",     ether.gwip);
  ether.printIp("Netmask: ", ether.netmask);
  ether.printIp("DNS IP: ",  ether.dnsip);
  Serial.println();
  
  ether.registerPingCallback(gotPinged);
  
  timer   = -9999999;
  polling = 0;
  i       = NUMSRVRS;
  cycles  = 0;
    
  digitalWrite(pinToToggle, !digitalRead(pinToToggle));
  delay(2000);
  digitalWrite(pinToToggle, !digitalRead(pinToToggle));
 
}

void loop () {
  
// Uncomment to change to no delay 
// if ( ( (micros() - timer) >= PING_DELAY) || !polling  ) {

//Comment this next line, if the above line is uncommented
 if ((micros() - timer) >= PING_DELAY) {
   if (polling) {
     ether.printIp("\n",ether.hisip);
     Serial.println(F("Timeout\n"));
     lcd.setCursor(0, 1);
     lcd.print("Timeout");
     if (cycles >= MAXCYCLES) while (1) blink();
   }
   else {
     polling = 1;
     lcd.clear();
     lcd.setCursor(0, 0);
     ++i;
     if (i >= NUMSRVRS) i = 0;
     strcpy_P(sbuffer, (char*)pgm_read_word(&(servers[i])));
     lcd.print(sbuffer);
     ether.parseIp(ether.hisip,sbuffer);
     ether.printIp("Pinging: ", ether.hisip);
   }
    
   cycles += 1;
   ether.clientIcmpRequest(ether.hisip);
   timer = micros();

  }

  word len = ether.packetReceive(); 
  word pos = ether.packetLoop(len); 

  if (len > 0 && ether.packetLoopIcmpCheckReply(ether.hisip)) {
    Serial.print("  ");
    ms = (micros() - timer) * 0.001;
    Serial.print(ms, 3);
    Serial.println(" ms\n");
    lcd.setCursor(0, 1);
    lcd.print(ms);
    lcd.print(" ms");
    polling   = 0;
    cycles    = 0;
  }
   
}

To use it in your environment, change the IP addresses to PING (and number of them) to suit your LAN. Also see the comments to use a static versus dynamic IP address for the monitor itself.